package {

	import flash.display.*;
	import flash.geom.*;
	import flash.events.*;
	
	[SWF(width='1024', height='768', backgroundColor='#000000', frameRate='30')]
	
	

	public class test extends Sprite {
		
		private var connections:uint = 2;
		private var count:uint = 10;
		private var speed:Number = 2.4;
		
		private var points:Vector.<Point> = new Vector.<Point>();
		private var pObjs:Vector.<pObject> = new Vector.<pObject>();

		public function test() {
			update();
			draw();
			stage.addEventListener(MouseEvent.CLICK,mouseClick);
			stage.addEventListener(Event.ENTER_FRAME,enterFrame);
		}
		
		private function mouseClick(e:MouseEvent):void {
			update();
		}
		
		private function enterFrame(e:Event):void {
			for (var i:uint=0;i<points.length;i++) {
				points[i].x += Math.sin(1000*Math.random())*speed;
				points[i].y += Math.sin(1000*Math.random())*speed;
			}
			draw();
		}
		
		private function update():void {
			points.length = 0;
			pObjs.length = 0;
			for (var i:uint=0;i<count;i++) points.push(new Point(Math.random()*stage.stageWidth,Math.random()*stage.stageHeight));
			var d:Number = 0;
			var p:Point;
			for (i=0;i<points.length;i++) {
				d = 0;
				var ps:Vector.<Point> = new Vector.<Point>();
				for(var j:uint=0;j<connections;j++) {
					p = getNear(points[i],d);
					d = distance(p,points[i]);
					ps.push(p);
				}
				pObjs.push(new pObject(points[i],ps));
			}
		}
		
		private function draw():void {
			var gd:Vector.<IGraphicsData> = new Vector.<IGraphicsData>();
			gd.push(basicStroke(.1,0xFFFFFF,1));
			for (var i:uint=0;i<pObjs.length;i++) {
				gd.push(basicStroke(.1,0xFFFFFF,pObjs[i].alpha));
				for(var j:uint=0;j<pObjs[i].points.length;j++) {
					gd.push(vectorLine(pObjs[i].point.x,pObjs[i].point.y,pObjs[i].points[j].x,pObjs[i].points[j].y));
				}
			}
			graphics.clear();
			graphics.drawGraphicsData(gd);
		}
		
		private function getNear(p:Point, min:Number=0):Point {
			var dist:Number = 10000;
			var oP:Point;
			for (var i:uint=0;i<points.length;i++) {
				var d:Number = distance(points[i],p);
				if(d<dist && d > min && p.x != points[i].x && p.y != points[i].y) {
					dist = d;
					oP = points[i];
				}	
			}
			return oP;
		}
		
		private function distance(p1:Point,p2:Point):Number {
			return Math.sqrt(Math.pow((p1.x-p2.x),2)+Math.pow((p1.y-p2.y),2));
		}
		
		private function vectorLine(x1:Number,y1:Number,x2:Number,y2:Number):GraphicsPath {
			var commands:Vector.<int> = new Vector.<int>(2,true);
			commands[0] = GraphicsPathCommand.MOVE_TO;
			commands[1] = GraphicsPathCommand.LINE_TO;
			var coords:Vector.<Number> = new Vector.<Number>(4,true);
			coords[0] = x1;
			coords[1] = y1;
			coords[2] = x2;
			coords[3] = y2;
			return new GraphicsPath(commands,coords);
		}
		
		private function basicStroke(thickness:Number=1, color:uint = 0, alpha:Number = 1.0):GraphicsStroke {
			return new GraphicsStroke(thickness,true,"normal","none","miter",3,new GraphicsSolidFill(color,alpha));
		}
		

	}

}


import flash.geom.*;

class pObject {
	
	private var _points:Vector.<Point>;
	private var _point:Point;
	private var _alpha:Number;
	
	public function get points():Vector.<Point> { return _points; }
	public function get point():Point { return _point; }
	public function get alpha():Number { return _alpha; }
	
	public function pObject(p:Point, points:Vector.<Point>) {
		_alpha = Math.random()*.7 + .1;
		_point = p;
		_points = points;
	}
	
}